comrak/flake.nix at main · kivikakk/comrak · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
{
  description = "comrak";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      nixpkgs,
      fenix,
      ...
    }:
    let
      systems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];
      eachSystem = nixpkgs.lib.genAttrs systems;
    in
    {

      packages = eachSystem (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          cargoToml = pkgs.lib.importTOML ./Cargo.toml;

          mkComrak =
            pkgs:
            pkgs.rustPlatform.buildRustPackage {
              pname = "comrak";
              inherit (cargoToml.package) version;

              src = ./.;
              cargoLock.lockFile = ./Cargo.lock;

              doCheck = false;
            };
        in
        rec {
          default = comrak;

          comrak = mkComrak pkgs;
          comrak-static = mkComrak pkgs.pkgsStatic;
        }
      );

      formatter = eachSystem (system: nixpkgs.legacyPackages.${system}.nixfmt);

      devShells = eachSystem (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
          fenixPkgs = fenix.packages.${system};

          mkShell =
            {
              name,
              toolchain,
              extraPkgs ? [ ],
            }:
            pkgs.mkShell {
              inherit name;

              packages = [
                (fenixPkgs.combine (
                  with toolchain;
                  [
                    cargo
                    rustc
                    rust-analyzer
                    clippy
                    rustfmt
                    rust-src
                    llvm-tools-preview
                  ]
                  ++ [
                    fenixPkgs.targets.wasm32-unknown-unknown.latest.rust-std
                  ]
                ))
              ]
              ++ (with pkgs; [
                re2c
                cargo-fuzz
                cargo-nextest
                cargo-flamegraph
                cargo-tarpaulin
                cargo-audit
                samply
                python3
                hyperfine
                bacon
              ])
              ++ extraPkgs;
            };
        in
        {
          default = mkShell {
            name = "comrak";
            toolchain = fenixPkgs.complete;
          };

          codspeed = mkShell {
            name = "comrak-codspeed";
            toolchain = fenixPkgs.complete;
            extraPkgs = [
              (pkgs.callPackage ./nix/codspeed.nix {
                rustPlatform = pkgs.makeRustPlatform {
                  cargo = fenixPkgs.complete.toolchain;
                  rustc = fenixPkgs.complete.toolchain;
                };
              })
            ];
          };

          stable = mkShell {
            name = "comrak-stable";
            toolchain = fenixPkgs.stable;
          };

          msrv = mkShell {
            name = "comrak-msrv";
            toolchain = fenixPkgs.toolchainOf {
              channel = "1.85.1";
              sha256 = "sha256-Hn2uaQzRLidAWpfmRwSRdImifGUCAb9HeAqTYFXWeQk=";
            };
          };
        }
      );
    };
}